***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 04, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt MMSZ5230B A K 
.param
+vc0 = 5.046e-11	vc1 = 4.616e-10		vc2 = 2.200		vc3 = 2.153e-9		vc4 = 9.809e0
+tc1 = 1.451e-2		tc2 = 5.651e-3		tc3 = 6.051e-3		tc4 = 5.001e-4
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 1.541e-15	   n = 1.048		  rs = 4.555e-1
+ibv = 20e-3		 nbv = 1.2		  bv = 4.705
+ikf = 1.4e-1
***** capacitance parameter *****
+cjo = 1.522e-10	   m = 3.803e-1		  vj = 8.475e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.136		 xti = 3
+trs1 = 1.005e-3	trs2 = 1.485e-6		tikf = 1e-3
+tbv1 = -3.262e-5	tbv2 = -3.439e-7	
.ends MMSZ5230B
*$
